模态分析在谐响应分析的作用

dxl

为什么有的谐响应分析需要模态分析,而有的不需要.

[ 本帖最后由 xuruikl 于 2007-10-19 15:21 编辑 ]

sysh320

<P>都需要的</P>

sysh320

我现在做模态分析，后面还没有做到，我看过都需要的，你在看看，估计不要的肯定是其他例子做过了，或者是知道它的模态，具体我也不是很清楚！

AaronSpark

没见过不需要进行模态分析的

sheman2001

一定需要吗？[em08]
我也见过没有做模态分析的就直接去做谐响应分析的！
这个是ANSYS验证手册中的VM90,就是直接做的谐响应分析!
我认为应该如果想知道谐响应分析中共振频率,需要做模态分析去找到固有频率.
但是只从做谐响应分析的角度来说,模态分析不是做谐响应分析的一个必要的步骤!

/COM,ANSYS MEDIA REL. 9.0 (10/15/2004) REF. VERIF. MANUAL: REL. 9.0
/VERIFY,VM90
/PREP7
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE, VM90, HARMONIC RESPONSE OF A TWO-MASS-SPRING SYSTEM
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND PRINTING, PAGE 178,EX 6.6-1
ANTYPE,HARMIC ! HARMONIC RESPONSE ANALYSIS
HROPT,REDUC ! REDUCED HARMONIC RESPONSE
HROUT,OFF ! PRINT RESULTS AS AMPLITUDES AND PHASE ANGLES
ET,1,COMBIN14,,,2
ET,2,MASS21,,,4
R,1,200 ! SPRING CONSTANT = 200
R,2,.5 ! MASS = 0.5
N,1
N,4,1
FILL
E,1,2
TYPE,2
REAL,2
E,2 ! MASS ELEMENT
TYPE,1
REAL,1
E,2,3 ! SPRING ELEMENT
TYPE,2
REAL,2
E,3 ! MASS ELEMENT
TYPE,1
REAL,1
E,3,4 ! SPRING ELEMENT
M,2,UX,3
OUTPR,BASIC,1
NSUBST,30 ! 30 INTERVALS WITHIN FREQ. RANGE
HARFRQ,,7.5 ! FREQUENCY RANGE FROM 0 TO 7.5 HZ
KBC,1 ! STEP BOUNDARY CONDITION
D,1,UY,,,4
D,1,UX,,,4,3
F,2,FX,200
FINISH
/SOLU
SOLVE
FINISH
/POST26
FILE,,rfrq
NSOL,2,2,U,X,2UX ! STORE UX DISPLACEMENTS
NSOL,3,3,U,X,3UX
PRVAR,2,3
*GET,X1,VARI,2,RTIME,1.5
*GET,X2,VARI,3,RTIME,1.5
*GET,X3,VARI,2,RTIME,4
*GET,X4,VARI,3,RTIME,4
*GET,X5,VARI,2,RTIME,6.5
*GET,X6,VARI,3,RTIME,6.5
/GRID,1 ! TURN GRID ON
/AXLAB,Y,DISP ! Y-AXIS LABEL DISP
PLVAR,2,3 ! DISPLAY VARIABLES 2 AND 3
*DIM,LABEL,CHAR,6,2
*DIM,VALUE,,6,3
LABEL(1,1) = 'X1, in ','X2, in ','X1, in ','X2, in ','X1, in ','X2, in '
LABEL(1,2) = 'f=1.5 Hz','f=1.5 Hz','f=4 Hz ','f=4 Hz ','f=6.5 Hz','f=6.5 Hz'
*VFILL,VALUE(1,1),DATA,.82272,.46274,.51145,1.2153,.58513,.26966
*VFILL,VALUE(1,2),DATA,ABS(X1),ABS(X2),ABS(X3),ABS(X4),ABS(X5),ABS(X6)
V1 = ABS(X1/.82272)
V2 = ABS(X2/.46274)
V3 = ABS(X3/.51145)
V4 = ABS(X4/1.2153)
V5 = ABS(X5/.58513)
V6 = ABS(X6/.26965)
*VFILL,VALUE(1,3),DATA,V1,V2,V3,V4,V5,V6
/COM
/OUT,vm90,vrt
/COM,------------------- VM90 RESULTS COMPARISON ---------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.5,' ',F10.5,' ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------
/COM,NOTE: THERE ARE VERIFIED RESULTS IN VM90 NOT CONTAINED IN
/COM,THIS TABLE
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm90,vrt

[ 本帖最后由 xuruikl 于 2007-10-22 09:19 编辑 ]

lyoly

应该要做的，谐响应分析的理论中，需要模型的模态来进行相应计算。

panwang

<P>模态分析是反映结构的动力学问题的，谐响应分析是结构对该频率的动力学响应，本质上都是结构的动力学问题。模态分析一般都是频域来分析结果的，而谐响应分析只能从时域来看结果（只有一个频率）。但好象谐响应分析也是先要做模态分析，再看某一频率（模态叠加法）的结构响应。（我的看法）</P>

ForCan2008

这个不一定，看你分析的时候用的什么方法，如果用模态叠加法就需要模态分析。如果用完全法就不需要，但可能要耗费更多的分析时间。

yaotao

应该做模态分析的

rodge

回答这么肯定，能做个详细的解释吗？

hhsy

原帖由 panwang 于 2006-5-15 08:52 发表

                               
登录/注册后可看大图

模态分析是反映结构的动力学问题的，谐响应分析是结构对该频率的动力学响应，本质上都是结构的动力学问题。模态分析一般都是频域来分析结果的，而谐响应分析只能从时域来看结果（只有一个频率）。但好象谐响应分 ...

模态分析是分析结构的动力特性，与结构受什么样的荷载没有关系，只要给定了质量、弹性模量、泊松比等材料参数，并施加了边界约束就可以得到此状态下的各阶自振频率和振型（也称为模态）。

谐响应分析是分析结构在不同频率的简谐荷载作用下的动力响应，是与结构所受荷载相关的，只是结构所受荷载的都是简谐荷载，而且荷载频率的变化范围在谐响应分析时要给出来。

比如，在ANSYS谐响应分析中要给出这样的语句
FK,3,FX,7071,7071        ！指定点荷载的实部和虚部（或者幅值和相位角）
HARFRQ,0,2.5,              ！指定荷载频率的变化范围，也就是说只分析结构所受频率从0到2.5HZ之间的荷载
NSUBST,100,                ！指定频率从0到2.5之间分100步进行计算

这样，结构所受的这个点荷载的表达式实际上是

F=(7071+i*7071)*exp(i*omiga*t)          !式中omiga从0到2.5*2*3.1415926变化

分析得到结果是各点物理量随频率变化的，但物理量的值一般为复数，包括实部的虚部，这可以从后处理LIST结点值看出来。

个人认为进行谐响应分析并不一定要先进行模态分析（也叫振型分析、振型分解等），而直接进行谐响应分析后查看结构的物理量随频率变化曲线时也会看到在结构的自振频率处响应会放大（共振）。如果已经进行过模态分析的话，会发现谐响应分析时的共振频率和模态分析提到的自振频率是一致的。但有些时候模态分析中得到的有些频率在谐响应分析的频响曲线里可能很不明显。因此，只能说在谐响应分析前进行一下模态分析可以对结构的自振特性有个了解，以便验证谐响应分析结果是否合理。

另外，谐响应分析应该是频域分析方法的一个部分。对于相地震那样的时间过程线，直接进行时域分析（ANSYS里用暂态分析）可得到结构随时间的响应。而如果进行频域分析，就应该通过傅立叶变换把时域地震曲线变为由多个简谐荷载的叠加，然后再以此简谐荷载做为谐响应分析时的荷载进行谐响应分析，最后再对谐响应分析得到的结果进行傅立叶逆变换得到时域的结果。不知道这种理解是否正确，我也没有用ANSYS这样做过。如果正确的话，时域分析和频域分析的结果应该是一致的。

以上是个人对ANSYS中模态分析和谐响应分析的一点看法，不正之处还请指正。

hhsy

这里给出一个谐响应分析的例子，以供参考，并没有进行模态分析
/BATCH  
KEYW,PR_SET,1   
KEYW,PR_STRUC,1
KEYW,PR_THERM,0
KEYW,PR_FLUID,0
KEYW,PR_ELMAG,0
KEYW,MAGNOD,0   
KEYW,MAGEDG,0   
KEYW,MAGHFE,0   
KEYW,MAGELC,0   
KEYW,PR_MULTI,0
KEYW,PR_CFD,0   
/GO
!*  

/prep7
!* define material proterties
mp,dens,1,2490   !mat 1 for dam
mp,ex,1,20e9
mp,prxy,1,.167  
mp,dens,2,2660   !mat 2 for foundation
mp,ex,2,10e9
mp,prxy,2,.28

!* define element type
et,1,PLANE42

!* define geometry
k, 1, 0.000000, 0.000000,0.000000
k, 2, 85.00000, 0.000000,0.000000
k, 3, 0.000000, 90.00000,0.000000
k, 4, 15.00000, 90.00000,0.000000
k, 5, 0.000000, 100.0000,0.000000
k, 6, 15.00000, 100.0000,0.000000
k, 7,-600.0000, 0.000000,0.000000
k, 8,-600.0000,-500.0000,0.000000
k, 9, 0.000000,-500.0000,0.000000
k,10, 85.00000,-500.0000,0.000000
k,11, 685.0000,-500.0000,0.000000
k,12, 685.0000, 0.000000,0.000000

a, 1, 2, 4, 3
a, 3, 4, 6, 5
a, 8, 9, 1, 7
a, 9,10, 2, 1
a,10,11,12, 2

asel,s,loc,y,0.,100.
aatt,1,,1
cm,adam,area
asel,s,loc,y,-500.,0
aatt,2,,1
cm,afound,area

allsel,all

!* mesh geometry
ESIZE,0,10
lsel,s,loc,y,91.,99.
lesize,all,,,4
mshape,0,2D
mshkey,1
allsel,all
amesh,all

finish
/solu
antype,3
HROPT,FULL  
HROUT,ON
EQSLV,FRONT,0,
PSTRES,0

! define constrains condition
lsel,s,loc,x,-601.,-599.
lsel,a,loc,x,684,686
lsel,a,loc,y,-501,-499
cm,uxy,line
DL,all, ,all,0

allsel,all

! define harmonic force
FK,3,FX,7071,7071

HARFRQ,0,2.5,
NSUBST,100,  
KBC,0

save
solve

junzifei

邮箱吧
我qq不长上
邮箱想起来时看一下
有事论坛上见
有问题我就上了
不过一直瞎忙
不知道什么时候能轻松一下
我都快抗不住了

lily_lee

看大家讨论了那么多，也没有说清楚问题，我也来说两句！
Ansys中进行谐响应分析的方法包括以下三种：
1）Full法，完全法；
2）Reduced法，即缩减法；
3）模态叠加法；
如果使用模态叠加法进行谐响应分析必须首先进行模态分析！

navy830411

感谢一下