基于ANSYS经典界面的室内声场的谐响应分析

canyiyuan

　　【问题描述】
　　一长方体封闭空间如下图所示，在其右上角部分有一四分之一圆柱形声源，其振动频率是80hz,其最大径向振幅是0.3048mm。在下部靠中间部分，有一窗户。现在要对该声场做谐响应分析，考察此时声场的声压驻波云图。

　　【问题分析】
　　使用FLUID30三维声场单元建模该室内声场。并对室内部分和与墙壁接触的空气部分分别用不同的单元建模。
　　使用先创建关键点，再创建直线，再创建体的方式创建体，然后对体划分网格。首先用耦合单元划分全部体，然后选中中间空气部分，修改其单元类型为空气单元。
　　对墙壁上节点约束所有位移。
　　对墙壁设置一种声阻抗，对窗户设置另外一种声阻抗。
　　对四分之一圆柱面设置强制径向位移以表达该柱面波的振幅。
　　设置为谐响应分析，并设置扫频的频率是80HZ
　　后处理中分别提取声压的实部和虚部的驻波云图。
　　使用命令流的方式进行求解。
　　该例子来自于ANSYS15的声场帮助中的例子(13.4. Example: Acoustic Harmonic Response in a Room)，但是经过了一些局部的调整，以更清晰的表达思路。
　　【求解过程】
　　1. 前处理
　　在命令窗口

　　中输入
　　/PREP7
　　以进入前处理器。
　　1.1 创建两种单元
　　在命令窗口中输入
　　ET,1,30
　　ET,2,30,,1
　　其中，
　　第1行说明创建FLUID30单元，它用于表达室内与墙壁及振动面接触的部分。
　　第2行创建FLUID30单元，它用于表达室内空气部分。
　　1.2 设置材料属性
　　在命令窗口中输入
　　RHO=1.2041
　　C0=343.24
　　Z0=RHO*C0
　　其中
　　这3行分别用于定义三个参数：空气密度，声音在空气中的传播速度，以及声阻抗。
　　在命令窗口中输入
　　MP,DENS,1,RHO
　　MP,SONC,1,C0
　　其中
　　这2行分别定义空气的密度和声速。
　　1.3 设置尺寸参数，及网格划分份数。
　　在命令窗口中输入
　　LEN=8.2296
　　HGT=6.0960
　　ZL=-0.3048
　　RAD=0.27432
　　其中
　　这4行分别定义该封闭空间的长，宽，高以及振动圆柱面的半径。
　　在命令窗口中输入
　　XDIV=29
　　YDIV=19
　　ZDIV=1
　　CDIV=2
　　其中
　　这4行分别定义该封闭空间的长，宽，高以及振动圆柱面的半径这四个方向的网格划分份数。
　　1.4 绘制顶面几何模型
　　在命令窗口中输入
　　K,1
　　K,2,LEN
　　K,3,LEN,HGT
　　K,4,,HGT
　　K,5,,,ZL
　　K,6,LEN,,ZL
　　K,7,LEN,HGT,ZL
　　K,8,,HGT,ZL
　　L,1,5,1
　　L,2,6,1
　　L,3,7,1
　　L,4,8,1
　　CIRC,3,RAD,7,2,90,2
　　其中
　　前一部分用于创建关键点，后一部分用于创建直线和圆。

　　1.5 绘制其它几何部分
　　在命令窗口中输入
　　ADRAG,5,6,,,,, 3
　　PIO4=ATAN(1)
　　LENC=COS(PIO4)
　　LENC=LENC*RAD
　　HGTC=HGT-LENC
　　LENC=LEN-LENC
　　其中
　　第一行用于拉伸出四分之一圆柱面，下面连续5行定义了5个参数。
　　结果如下图

　　在命令窗口中输入
　　K,15,,HGTC
　　K,16,,HGTC,ZL
　　K,17,LENC
　　K,18,LENC,,ZL
　　其中
　　这4行进一步创建4个关键点
　　结果如下图

　　在命令窗口中输入
　　L,1 ,17,XDIV
　　L,10,15,XDIV
　　L,11,4 ,XDIV
　　L,17,10,YDIV
　　L,15, 1,YDIV
　　L,2 ,9 ,YDIV
　　L,5 ,18,XDIV
　　L,13,16,XDIV
　　L,14,8 ,XDIV
　　L,18,13,YDIV
　　L,16,5 ,YDIV
　　L,6 ,12,YDIV
　　其中
　　这些行进一步创建一些直线
　　结果如下图

　　1.6 绘制几何体
　　在命令窗口中输入
　　V,1 ,17,10,15, 5,18,13,16
　　V,15,10,11,4 ,16,13,14,8
　　V,17,2 ,9 ,10,18,6 ,12,13
　　其中
　　这3行用于创建三个体

　　1.7 对体划分网格
　　在命令窗口中输入
　　ESIZE,,CDIV
　　VMESH,ALL
　　ALLS
　　其中
　　第1,2行设置了网格尺寸，并对体划分了网格，此时所有的单元都是耦合单元类型。
　　第3行选择所有对象，以便后面的操作。
　　网格划分结果如下图
　　1.8 改变边界上的单元类型
　　在命令窗口中输入
　　NSEL,S,LOC,X,0.0
　　NSEL,A,LOC,Y,0.0
　　NSEL,A,LOC,X,LEN
　　NSEL,A,LOC,Y,HGT
　　LOCAL,11,1,LEN,HGT
　　NSEL,A,LOC,X,RAD
　　ESLN
　　ESEL,INVE
　　TYPE,2
　　EMODIF,ALL
　　ALLS
　　其中
　　前面4行用于选择壁面的节点
　　然后选择与壁面节点关联的单元
　　接着去掉这些边界单元，只剩下房间内的空气部分
　　然后把空气部分替换成为空气单元类型。
　　最后选择所有对象
　　此时，如果打开单元类型的编号控制，可以看到下述图形。可见，整个场被划分为两部分：边界部分和中间部分。边界部分是用耦合单元表示的，而中间部分是用纯空气单元表示的。

　　1.10 对振动面设置为流固耦合边界条件
　　在命令窗口中输入
　　NSEL,S,LOC,X,RAD
　　ESLN
　　SF,ALL,FSI
　　其中
　　第1行选择半径上的所有节点
　　第2行选择与这些节点关联的单元
　　第3行设置这些单元为耦合边界。
　　1.11 设置墙壁上所有节点的位移是零
　　在命令窗口中输入
　　CSYS,0
　　NSEL,S,LOC,X,0.0
　　NSEL,A,LOC,Y,0.0
　　NSEL,A,LOC,X,LEN
　　NSEL,A,LOC,Y,HGT
　　D,ALL,UX,,,,,UY,UZ
　　其中
　　中间4行选择在壁面上的所有节点
　　最后1行设置这些节点不能发生位移
　　结果如下

　　1.12 设置耦合面上的径向振动幅值
　　在命令窗口中输入
　　CSYS,11
　　NSEL,S,LOC,X,RAD
　　NROTAT,ALL
　　D,ALL,UX,.003048
　　D,ALL,UY,,,,,UZ
　　其中
　　这几行用于说明，将圆柱振动面上的所有节点，设置其径向位移振幅是0.3048mm,而其它方向位移是零。
　　设置完毕后，该圆柱面上结果如下图
　　1.13 设置墙壁的阻抗值
　　在命令窗口中输入
　　ALLS
　　CSYS,0
　　NSEL,S,LOC,X,0.0
　　NSEL,A,LOC,X,LEN
　　NSEL,A,LOC,Y,0.0
　　NSEL,A,LOC,Y,HGT
　　SF,ALL,IMPD,Z0/0.04
　　其中
　　中间4行用于选择墙壁面上所有的节点，然后设置壁面节点的阻抗值是Z0/0.04
　　此时，壁面上出现红色方框如下图。
　　1.14 设置窗户的阻抗值
　　在命令窗口中输入
　　HX=LENC/XDIV
　　NSEL,S,LOC,Y,0.0
　　NSEL,R,LOC,X,13*HX,17*HX
　　SF,ALL,IMPD,Z0/0.7 ! Window impedance
　　ALLS
　　FINISH
　　其中
　　第1-3行用于选择底面中间地方的一些节点
　　第4行用于对这些节点设置特殊的阻抗。该区域表示该封闭空间的窗户部分。

　　2. 求解
　　在命令窗口中输入
　　/SOLU
　　ANTYPE,HARM
　　HARF,80,80
　　SOLVE
　　FINISH
　　其中
　　上述几行依次表明，要进行谐响应分析，设置激励频率是80HZ，也就是圆柱表面的激励频率80HZ，(前面知道，振副是0.3048mm)，这样就完整的表达了声源特征。
　　3. 后处理

　　3.1 打印声压的实部
　　在命令窗口中输入
　　/post1
　　SET,1,1
　　EPLOT
　　/EDGE,1
　　/TITLE,-ROOM ACOUSTICS- * REAL PART OF PRESSURE
　　PLNS,PRES
　　其中
　　上面几行用于选择结果集，并打印声压实部的驻波云图。
　　结果如下
　　3.1 打印声压的虚部
　　在命令窗口中输入
　　SET,1,1,,1
　　/TITLE,-ROOM ACOUSTICS- * IMAG. PART OF PRESSURE
　　PLNS,PRES
　　其中
　　上面几行用于选择结果集，并打印声压虚部的驻波云图。
　　结果如下



转自：http://blog.sina.com.cn/s/blog_9e19c10b0102vkvh.html