求助！ANSYS推出试验分析

lovecn1986

小弟初学者，目前正在做一个栓钉的推出试验仿真，本来按照原来的计算需要在钢梁顶面加上30MPa的面荷载，但目前不知道什么原因加到22MPa就再也加不上去了，程序就不收敛了。在程序运算过程中有一部分单元的形状超过了正常的限制，但可以算过去。混凝土采用的是C60的。求高手指教一下！以下是全部命令流：

FINISH
/CLE
/REPLOT
/Config,nproc,2           !打开多核
/PREP7

!输入单元类型
ET,1,solid65                   !混凝土
ET,2,solid45                   !栓钉和钢梁

!输入材料属性
MP,EX,1,36500      !  混凝土弹模
mp,prxy,1,0.167    !  混凝土泊松比

MP,EX,2,200000     !  钢梁弹模
mp,prxy,2,0.31     !  钢梁泊松比

MP,EX,3,214870     !  剪力钉弹模
mp,prxy,3,0.31     !  剪力钉泊松比

!定义材料屈服准则
!混凝土
tb,concr,1
tbdata,,0.3,0.9,-1,-1
tb,miso,1,,17
tbpt,,0,0
tbpt,,0.2e-3,7.3
tbpt,,0.4e-3,14.6
tbpt,,0.6e-3,21.9
tbpt,,0.8e-3,29.2
tbpt,,1e-3,36.3
tbpt,,1.2e-3,43.2
tbpt,,1.4e-3,49.5
tbpt,,1.6e-3,54.7
tbpt,,1.8e-3,58.4
tbpt,,2e-3,60
tbpt,,2.03e-3,60
tbplot,miso

!钢梁
tb,miso,2
tb,miso,2,1,4,0   
tbtemp,0
tbpt,,0,0
tbpt,,1.5e-3,300
tbpt,,3.5e-3,300
tbpt,,8.0e-3,400
tbplot,miso

!剪力钉
tb,miso,3
tb,miso,3,1,5,0   
tbtemp,0
tbpt,,0,0
tbpt,,0.8e-3,171.896
tbpt,,1.5e-3,300
tbpt,,3.5e-3,300
tbpt,,8.0e-3,400
tbplot,miso

!建立节点
k,214, 0  ,0  ,-250
k,222, 0  ,0  ,0   
k,3556,0  ,500,-250
k,3677,0  ,500,0   
k,4303,50 ,275,-97.5
k,4378,50 ,275,-91  
k,4453,50 ,275,-80  
k,4308,60 ,275,-97.5
k,4383,60 ,275,-91  
k,4458,60 ,275,-80  
k,4438,300,275,-91  
k,4513,300,275,-80  
k,1876,301,275,-91  
k,1886,301,275,-80  
k,1022,301,50 ,-5   
k,1025,317,50 ,-5   
k,1030,317,50 ,0   
k,1027,301,50 ,0   
k,1457,301,650,-5   
k,1460,317,650,-5   
k,1465,317,650,0   
k,1462,301,650,0   
k,946 ,301,50 ,-150
k,954 ,317,50 ,-150
k,1381,301,650,-150
k,1389,317,650,-150
k,1310,496,50 ,-5   
k,1311,496,50 ,0   
k,1745,496,650,-5   
k,1746,496,650,0

!生成混凝土面
a,3556,3677,222,214
wprota,,,90
cyl4,80,275,0,0,17.5,,
asba,1,2
voffst,3,300,

!生成栓钉所需点
kgen,2,1876,,,16
kgen,2,1886,,,16

!连接栓钉面
a,4303,4308,4383,4378
a,4378,4383,4458,4453
a,4383,4438,4513,4458
a,4438,1876,1886,4513
a,1876,13,14,1886

!旋转生成栓钉
vrotat,11,12,13,14,15,,4453,14,,4
vsel,u,,,1
cm,dz,volu
allsel

!生成钢梁体
kdele,1022
kdele,1457
v,946,954,1030,1027,1381,1389,1465,1462
v,1030,1025,1310,1311,1465,1460,1745,1746

!在钢梁上开洞
vsbv,22,dz,,delete,keep
vsel,s,,,23,24
cm,gl,volu
allsel

!生成栓钉周围混凝土
kgen,2,4453,,,-50
kgen,2,4378,,,-50

a,1,4303,4378,37
a,37,4378,4453,36
a,4308,11,4438,4383

vrotat,81,83,93,,,,36,4513,,4
cmsel,u,gl
vsel,u,,,1
cmsel,u,dz
cm,hnt1,volu

!栓钉周围混凝土切割
vsel,s,,,1
kwpave,36
wprota,,,-90
vsbw,all
wpoffs,,,-35
vsbw,all
wpoffs,,,70
vsbw,all

wprota,,-90,
vsbw,all
wpoffs,,,-35
vsbw,all
wpoffs,,,70
vsbw,all
wpcsys,,0
cm,hnt2,volu

!栓钉周围钢梁切割
cmsel,s,gl
cmdele,gl
kwpave,1886
vsbw,all
wpoffs,,,-22
vsbw,all
wpoffs,,,44
vsbw,all

wprota,,-90,
vsbw,all
wpoffs,,,-22
vsbw,all
wpoffs,,,44
vsbw,all
wpcsys,,0
cm,gl,volu

!对各体再切分
!hnt
cmsel,s,hnt1
cmsel,a,hnt2
cmdele,hnt1
cmdele,hnt2
wpoffs,,,-150
vsbw,all
wpoffs,,,-50
vsbw,all

wprota,,-90,
wpoffs,,,100
vsbw,all
wpoffs,,,300
vsbw,all

wprota,,,90
wpoffs,,,50
vsbw,all
wpoffs,,,10
vsbw,all
wpoffs,,,60
vsbw,all
wpoffs,,,60
vsbw,all
wpoffs,,,60
vsbw,all
wpcsys,,0
cm,hnt,volu

vsel,r,loc,z,-97.5,-62.5
vsel,r,loc,y,257.5,292.5
cm,hnt1,volu

cmsel,s,hnt
cmsel,u,hnt1
vsel,r,loc,z,-115,-45
vsel,r,loc,y,240,310
cm,hnt2,volu

!gl
cmsel,s,gl
cmdele,gl
wprota,,-90,
wpoffs,,,150
vsbw,all
wpoffs,,,250
vsbw,all
wpoffs,,,100
vsbw,all

wprota,,,90
wpoffs,,,400
vsbw,all
wpcsys,,0
cm,gl,volu

vsel,r,loc,z,-102,-58
vsel,r,loc,y,253,297
cm,gl1,volu

!dz
cmsel,s,dz
cmdele,dz
wprota,,,90
wpoffs,,,120
vsbw,all
wpoffs,,,60
vsbw,all
wpoffs,,,60
vsbw,all
wpcsys,,0
cm,dz,volu
allsel
cmsel,all
!体切割完毕

!对混凝土进行粘结
cmsel,s,hnt
cmdele,hnt
cmdele,hnt1
cmdele,hnt2
vglue,all
cm,hnt,volu

vsel,r,loc,z,-97.5,-62.5
vsel,r,loc,y,257.5,292.5
cm,hnt1,volu

cmsel,s,hnt
cmsel,u,hnt1
vsel,r,loc,z,-115,-45
vsel,r,loc,y,240,310
cm,hnt2,volu

!赋予材料属性
cmsel,s,hnt
vatt,1,,1,                               !混凝土赋予材料特性

cmsel,s,dz
vatt,3,,2,                           !栓钉赋予材料特性

cmsel,s,gl
vatt,2,,2,                             !钢梁赋予材料特性

!划分网格
!hnt1,hnt2
cmsel,s,hnt1
cmsel,a,hnt2
mshape,0,3d
mshkey,1
aslv,s
lsla,s
lesize,all,,,2
vsweep,all

!hnt
cmsel,s,hnt
cmsel,u,hnt1
cmsel,u,hnt2
mshape,0,3d
mshkey,1
aslv,s
lsla,s
lesize,all,,,2
vmesh,all

!dz
cmsel,s,dz
mshape,0,3d
mshkey,1
aslv,s
lsla,s
lesize,all,,,2
vmesh,all

!gl1
cmsel,s,gl1
mshape,0,3d
mshkey,1
aslv,s
lsla,s
lesize,all,,,2
vsweep,all

!gl
cmsel,s,gl
cmsel,u,gl1
mshape,0,3d
mshkey,1
aslv,s
lsla,s
lesize,all,,,2
vmesh,all
!网格划分完毕

!选择边界面
asel,s,loc,x,496
cm,mian2,area
allsel
asel,s,loc,z,0
cm,mian1,area
allsel
asel,s,loc,y,0
cm,mian3,area

asel,s,,,mian1                            !面1施加对称约束
nsla,s,1
dsym,symm,z,0

asel,s,,,mian2                            !面2施加对称约束
nsla,s,1
dsym,symm,x,0

da,mian3,all                              !面3施加固结约束

allsel,all

!在顶面上施加面荷载
asel,s,loc,y,650                          !选取荷载面
cm,hza,area                               !定义荷载面
allsel

!定义荷载步
/solu
antype,0
nlgeom,on                                 !打开大变形选项
pred,on
autots,on
eqslv,sparse
lnsrch,on
nropt,full,,on
cnvtol,f,,0.06,2,0.5     
!cnvtol,u,,0.2,2,1                       
outres,all,all

time,1
kbc,0
neqit,50                              !迭代次数
nsubst,100
sfa,hza,1,pres,22
allsel
solve

将倒数第三行最后的22改到30就算不过去了，力的单位为N，长度单位为mm。

jubinskd

虽然不会解决你的问题。但是从你的命令流中学会了如何设置迭代次数。谢谢了