做一个悬臂梁的周期正弦激励，用瞬态分析，出现错误提示

huazi071783

本人想做一个悬臂梁在周期余弦荷载作用下的响应，用瞬态分析，总是错误提示：Present time 0.1 is less than or equal to the previous time in a transient analisys。我想设置每一个荷载步为0.1秒，每个荷载步有10个荷载子步。这个错误提示不知道什么原因，请高手指点，谢谢！下面是我的命令流
/PREP7                     
ET,1,SHELL63                      !单元属性
l=1.0                             !梁长
h=0.05                            !梁高
b=0.03                            !梁宽
EX0=73E9
PRXY0=0.33
DENS0=2270
N0=160                             !长度方向单元数
Nh=5                            !高度方向单元数
!生成节点
*DO, j, 1, Nh+1
  *DO, i, 1, N0+1
    N,i+(j-1)*(N0+1),(i-1)*l/N0,(j-1)*h/(Nh),0,,,,
  *ENDDO
*ENDDO
!生成单元  
*DO,j,1,Nh
  *DO,i,1,N0
   E,i+(j-1)*(N0+1),i+1+(j-1)*(N0+1),i+1+j*(N0+1),i+j*(N0+1)
  *ENDDO
*ENDDO
!单元厚度
R,1,b, , , , , ,
RMORE, , , ,
RMORE   
RMORE, ,
!
!材料属性
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,EX0   
MPDATA,PRXY,1,,PRXY0  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,DENS,1,,DENS0   
!施加约束和分析类型
/SOL
ANTYPE,trans
TRNOPT,FULL
LUMPM,0
*do,i,1,Nh
   D,1+(i-1)*(N0+1), , , , , ,ALL, , , , ,  
*enddo
D,all, ,0, , , ,UZ, , , , ,
!施加余弦周期力，荷载步设定
timint,on,all                      !打开瞬态效应
alphad, 0.02                      !a阻尼
betad,0.004                       !beta阻尼
*do,i,1,100
  time,0.1                        !作用时间
  !deltime,0.01                   !荷载子步
  nsubst,10
  kbc,0                           !斜坡力
  LSWRITE, 1                      !读入荷载步
  f,3530,fy,-cos(6.3*i)           !施加正弦力
  OUTRES, all, all                !结果输出频率效应
  solve
*enddo
finish

Rainyboy

time 命令不是楼主所理解的当前载荷步的作用时间，二就是当前载荷步在时间轴上出现的位置。
按楼主原意，应该是
第一步：time,0.1
第二步：time,0.2
第三步：time,0.3

因此，应该在循环中将time,0.1改为形如：time,0.1*i

huazi071783

回复 2 # Rainyboy 的帖子

谢谢，我试试先哈

huazi071783

回复 1 # huazi071783 的帖子

就是你说的问题，这个问题已经解决了，谢谢

xlda

LSWRITE, 1       读入载荷步
是不是应该也是
LSWRITE, i
??