xuruikl 发表于 2006-12-18 10:12

贴一些蠕变分析例子

最近不少人在问蠕变方面的问题，我就共享几个这方面的例子给大家
先把帮助文档里面的几个例子贴出来

[ 本帖最后由 xuruikl 于 2006-12-18 10:16 编辑 ]

xuruikl 发表于 2006-12-18 10:18

绷紧的螺钉的应力松弛现象
/COM,ANSYS MEDIA REL. 8.1 (03-15-2004) REF. VERIF. MANUAL: REL. 8.1
/VERIFY,VM132
/PREP7
/TITLE, VM132, STRESS RELAXATION OF A BOLT DUE TO CREEP
C***    STR. OF MATL., TIMOSHENKO, PART 2, 3RD ED., PAGE 531
ANTYPE,STATIC
ET,1,LINK1             ! SPAR ELEMENT
R,1,1,(1/30000)      ! INITIAL STRAIN
MP,EX,1,30E6
TB,CREEP,1
TBDATA,1,4.8E-30,7   ! CREEP PROPERTIES
N,1
N,2,10
E,1,2
BFUNIF,TEMP,900      ! UNIFORM TEMPERATURE
TIME,1000
KBC,1
D,ALL,ALL            ! FIX ALL DOFS
FINISH
/SOLU   
SOLCONTROL,0
NSUBST,100
OUTPR,BASIC,10         ! PRINT BASIC SOLUTION FOR EVERY 10TH SUBSTEP
OUTRES,ESOL,1          ! STORE ELEMENT SOLUTION FOR EVERY SUBSTEP
SOLVE
FINISH
/POST26
ESOL,2,1,,LS,1,SIG   ! STORE AXIAL STRESS
PRVAR,2                ! PRINT AXIAL STRESS VS TIME
*GET,T190,VARI,2,RTIME,190
*GET,T420,VARI,2,RTIME,420
*GET,T690,VARI,2,RTIME,690
*GET,T880,VARI,2,RTIME,880
*GET,T950,VARI,2,RTIME,950
*status,parm
*DIM,LABEL,CHAR,5,2
*DIM,VALUE,,5,3
LABEL(1,1) = 'SIG @ ','SIG @ ','SIG @ ','SIG @ ','SIG @ '
LABEL(1,2) = '190 hr','420 hr','690 hr','880 hr','950 hr'
*VFILL,VALUE(1,1),DATA,975,950,925,910,905
*VFILL,VALUE(1,2),DATA,T190,T420,T690,T880,T950
V1 = ABS(T190/975)
V2 = ABS(T420/950)
V3 = ABS(T690/925)
V4 = ABS(T880/910)
V5 = ABS(T950/905)
*VFILL,VALUE(1,3),DATA,V1,V2,V3,V4,V5
/COM
/OUT,vm132,vrt
/COM,------------------- VM132 RESULTS COMPARISON -------------
/COM,
/COM,               |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.0,'',F10.0,'   ',1F5.2)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm132,vrt

xuruikl 发表于 2006-12-18 10:19

/COM,ANSYS MEDIA REL. 8.1 (03-15-2004) REF. VERIF. MANUAL: REL. 8.1
/VERIFY,VM133
/PREP7
MP,PRXY,,0.3
/TITLE, VM133, MOTION OF A ROD DUE TO IRRADIATION INDUCED CREEP
C***    REFERENCE - ANY BASIC CALCULUS BOOK
ANTYPE,STATIC
ET,1,BEAM23            ! PLASTIC BEAM
R,1,.25,.0052083,.5    ! AREA, IZZ, HEIGHT
MP,EX,1,300
TB,CREEP,1
TBDATA,55,0.5E-12,1E10 ! CREEP EQUATION CONSTANTS K1 AND K2
TBDATA,66,5            ! SELECT IRRADIATION INDUCED CREEP EQUATION
N,1
N,2,1
E,1,2
D,1,ALL                ! FIX ONE END
F,2,FX,.25             ! FORCE INDUCING CONSTANT STRESS
FINISH
/SOLU   
!SOLCONTROL,0
BFE,1,TEMP,1,1000,1000,1000,1000 ! APPLY CONSTANT TEMPERATURE
BFE,1,FLUE,1,0,0,0,0             ! APPLY ZERO FLUENCE
TIME,1E-8            ! NEAR ZERO TIME FOR FIRST LOAD STEP
OUTPR,BASIC,1          ! PRINT BASIC ELEMENT SOLUTION
OUTRES,EPCR,1          ! STORE CREEP STRAIN RESULTS FOR EVERY SUBSTEP
CNVTOL,F,,,,1E-6       ! NEAR ZERO VALUE FOR MINREF FIELD
CNVTOL,M,-1            ! CONVERGENCE CRITERION BASED UPON MOMENTS IS
                     !REMOVED AS IT IS NOT NEEDED FOR THIS TEST
SOLVE                  ! LOAD STEP 1
NSUBST,50,500,50
TIME,5
OUTPR,BASIC,5
BFE,1,FLUE,1,5E10,5E10,5E10,5E10 ! FINAL FLUENCES (RAMPED)
SOLVE                  ! LOAD STEP 2
FINISH
/POST26
ESOL,2,1,,LEPCR,1,EPCR ! STORE CREEP STRAIN
PRVAR,2                ! PRINT STRAIN VARIATION WITH TIME
*GET,T1,VARI,2,RTIME,0
*GET,T2,VARI,2,RTIME,.5
*GET,T3,VARI,2,RTIME,1
*GET,T4,VARI,2,RTIME,5
*status,parm
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'CRP STR @','CRP STR @','CRP STR @','CRP STR @'
LABEL(1,2) = '0 hr','.5 hr','1 hr','5 hr'
*VFILL,VALUE(1,1),DATA,0,.00197,.00316,.00497
*VFILL,VALUE(1,2),DATA,T1,T2,T3,T4
*VFILL,VALUE(1,3),DATA,000,ABS(T2/.00197),ABS(T3/.00316),ABS(T4/.00497)
/COM
/OUT,vm133,vrt
/COM,------------------- VM133 RESULTS COMPARISON -------------
/COM,
/COM,               |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.5,'',F10.5,'   ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vm133,vrt

xuruikl 发表于 2006-12-18 10:19

/COM,ANSYS MEDIA REL. 8.1 (03-15-2004) REF. VERIF. MANUAL: REL. 8.1
/VERIFY,vm224
JPGPRF,500,100,1             ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/TITLE,VM224, Implicit Creep Under Biaxial Load
/COM, NAFEMS Fundamental Tests of Creep Behavior, Becker and Hyde
/NOPR
/COM,
/COM, 2D CREEP TESTS WITH BIAXIAL CONSTANT LOAD,
/COM, REFERENCE: TEST 10(A) FROM NAFEMS R0027.
/COM,
/COM, EXPECTED RESULTS:
/COM,       TIME | EPCRX| EPCRY                  
/COM,   ----------------------------         
/COM,      0.0 | 0.0    | -0.0   
/COM,      0.1 | 0.0427 | -0.0427
/COM,      1.0 | 0.135| -0.135
/COM,      5.0 | 0.3019 | -0.3019
/COM,       10.0 | 0.4269 | -0.4269
/COM,       50.0 | 0.9546 | -0.9546
/COM,      100.0 | 1.35   | -1.35   
/COM,      500.0 | 3.019| -3.019
/COM,   1000.0 | 4.2691 | -4.2691
/COM,
/PREP7
C*** PARAMETRIC INPUT FOR CREEP CONSTANTS (PRIMARY CREEP)!***
*SET,C1,1.5625E-14                        !ASSIGN VALUE
*SET,C2,5.0                                !ASSIGN VALUE
*SET,C3,-0.5                                !ASSIGN VALUE
*SET,C4,0                                !ASSIGN VALUE
C***TIME PARAMETER
*SET,HOUR,1000                                !ASSIGN VALUE
C***   ELASTIC CONSTANT
MP,EX,1,200E3                                !DEFINE YOUNG'S MODULUS
MP,NUXY,1,0.3                                !DEFINE POISON'S RATIO
TUNIF,HOT                                !ASSIGN TEMP TO NODES
TOFF,OFFS                                !SPECIFY TEMP RELATIVE TO ABSOLUTE VALUES
TB,CREEP,1,,,6                                !ACTIVATE DATA TABLE
TBDATA,1,C1,C2,C3,C4                        !DEFINE DATA FOR TABLE
SAVE                                        !SAVE
/PREP7
N,1,0,0,0
N,2,100,0
N,3,100,100
N,4,0,100
N,5,50,0
N,6,100,50
N,7,50,100
N,8,0,50
N,9,50,50
ET,1,PLANE182
KEYOPT,1,1,1
KEYOPT,1,3,0
E,1,5,9,8
E,5,2,6,9
E,9,6,3,7
E,8,9,7,4
NALL
NSEL,S,LOC,X
D,ALL,UX
NSEL,S,LOC,Y
D,ALL,UY
NALL
/SOLU
NSEL,S,LOC,X,100
SF,ALL,PRES,-200
NALL
NSEL,S,LOC,Y,100
SF,ALL,PRES,200
NALL
RATE, OFF
DELT,1.0E-8,1.0E-9,1.0E-8
TIME, 1.0E-8
/OUT,SCRATCH
OUTRES,ESOL,ALL
SOLVE
/OUT
RATE, ON, ON
DELT,1E-5,1E-5,100
TIME,1000
/OUT,SCRATCH
SOLVE
/OUT
FINISH
/POST26
ESOL,2,1,,EPCR,X
ESOL,3,1,,EPCR,Y
PRVAR,2,3
PLVAR,2,3
*GET,RES1X,VARI,2,RTIME,1000
*GET,RES1Y,VARI,3,RTIME,1000
FINISH
PARSAV,ALL
RESUME
PARRES,CHANGE
/PREP7
N,1,0,0,0
N,2,100,0
N,3,100,100
N,4,0,100
N,5,50,0
N,6,100,50
N,7,50,100
N,8,0,50
ET,1,PLANE183
KEYOPT,1,3,0
E,1,2,3,4,5,6,7,8
NALL
NSEL,S,LOC,X
D,ALL,UX
NSEL,S,LOC,Y
D,ALL,UY
NALL
/SOLU
NSEL,S,LOC,X,100
SF,ALL,PRES,-200
NALL
NSEL,S,LOC,Y,100
SF,ALL,PRES,200
NALL
RATE, OFF
DELT,1.0E-8,1.0E-9,1.0E-8
TIME, 1.0E-8
/OUT,SCRATCH
SOLVE
/OUT
RATE, ON, ON
DELT,1E-5,1E-5,100
TIME,1000
/OUT,SCRATCH
OUTRES,ESOL,ALL
SOLVE
/OUT
FINISH
/POST26
ESOL,2,1,,EPCR,X
ESOL,3,1,,EPCR,Y
PRVAR,2,3
PLVAR,2,3
*GET,RES2X,VARI,2,RTIME,1000
*GET,RES2Y,VARI,3,RTIME,1000

*DIM,LABEL1,CHAR,2
*DIM,VALUE1,,2,3
LABEL1(1) = ' ECRXX ',' ECRYY '
*VFILL,VALUE1(1,1),DATA,4.2691,-4.2691
*VFILL,VALUE1(1,2),DATA,RES1X,RES1Y
*VFILL,VALUE1(1,3),DATA,ABS(RES1X/4.2691),ABS(RES1Y/(-4.2691))

*DIM,LABEL2,CHAR,2
*DIM,VALUE2,,2,3
LABEL2(1) = ' ECRXX ',' ECRYY '
*VFILL,VALUE2(1,1),DATA,4.2691,-4.2691
*VFILL,VALUE2(1,2),DATA,RES2X,RES2Y
*VFILL,VALUE2(1,3),DATA,ABS(RES2X/4.2691),ABS(RES2Y/(-4.2691))

/OUT,vm224,vrt
/COM
/COM,------------------- VM224 RESULTS COMPARISON ---------------------
/COM,
/COM,            |   TARGET   |   ANSYS   |   RATIO
/COM,
/COM, PLANE182
/COM,
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),VALUE1(1,3)
(1X,A8,'      ',F7.4,'      ',F7.4,'   ',1F5.3)
/COM,
/COM, PLANE183
/COM,
*VWRITE,LABEL2(1),VALUE2(1,1),VALUE2(1,2),VALUE2(1,3)
(1X,A8,'      ',F7.4,'      ',F7.4,'   ',1F5.3)
/COM,----------------------------------------------------------------
/OUT

FINISH
*LIST,vm224,vrt

xuruikl 发表于 2006-12-18 10:20

/COM,ANSYS MEDIA REL. 10.0 (05/31/2005) REF. VERIF. MANUAL: REL. 10.0
/VERIFY,VM200
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/SHOW,JPEG
/PREP7
/TITLE, VM200, VISCOELASTIC SANDWICH SEAL ANALYSIS
/COM, ----- 2-D ANALYSIS -----
/COM, "FE CALCULATIONS OF RESIDUAL STRESSES ....",SOULES ET AL.
ET,1,VISCO88,,,1 ! AXISYMMETRIC 2-D VISCOELASTIC ELEMENT
*CREATE,MAC1 ! MACRO FOR MATERIAL PROPERTIES
/COM, MATERIAL ONE IS G-11 GLASS AND MATERIAL TWO IS ALUMINA
/COM, NOTE THAT ALUMINA IS AN ELASTIC MATERIAL THEREFORE IT
/COM, DOES NOT HAVE VISCOELASTICITY AND STRUCTURAL RELAXATION
/COM, MATERIAL PROPERTIES OF ALUMINA
TB,EVISC,2
TBDATA,31,52.6E-7 ! THERMAL EXPANSION COEFFICENTS FOR ALUMINA
TBDATA,32,.119E-7 ! LOCATIONS 31-33
TBDATA,33,-1.0E-11
TBDATA,46,1.435E5 ! SHEAR MODULUS AT TIME = 0
TBDATA,47,1.435E5 ! SHEAR MODULUS AT TIME = INFINITY
TBDATA,48,3.11E5 ! BULK MODULUS AT TIME = 0
TBDATA,49,3.11E5 ! BULK MODULUS AT TIME = INFINITY
/COM, MATERIAL PROPERTIES OF G-11 GLASS
TB,EVISC,1
TBDATA,1,6.45D4 ! H/R
TBDATA,2,0.53 ! VALUE OF X
TBDATA,3,6 ! NO. OF MAXWELL ELEMENTS FOR STRUCTURAL RELAXATION
TBDATA,6,0.108 ! COEFFICIENTS OF THE MAXWELL ELEMENTS FOR
TBDATA,7,0.443 ! VOLUME DECAY (STRUCTURAL RELAXATION)
TBDATA,8,0.166 ! LOCATIONS 6-11
TBDATA,9,0.161
TBDATA,10,0.046
TBDATA,11,0.076
TBDATA,16,3.00 ! RELAXATION TIMES FOR VOLUME DECAY FUNCTION
TBDATA,17,0.671 ! LOCATIONS 16-21
TBDATA,18,0.247
TBDATA,19,0.091
TBDATA,20,0.033
TBDATA,21,0.008
TBDATA,26,3.43E-5 ! THERMAL EXPANSION COEFF. IN LIQUID STATE
TBDATA,31,64.7E-7 ! THERMAL EXPANSION COEFF. IN GLASS (SOLID) STATE
TBDATA,32,.02E-7 ! LOCATIONS 31-32
TBDATA,36,618 ! FICTIVE TEMPERATURE LOCATIONS 36-41
TBDATA,37,618
TBDATA,38,618
TBDATA,39,618
TBDATA,40,618
TBDATA,41,618
TBDATA,46,2.79D4 ! SHEAR MODULUS AT TIME = 0
TBDATA,47,0.0D0 ! SHEAR MODULUS AT TIME = INFINITY
TBDATA,48,6.05D4 ! BULK MODULUS AT TIME = 0
TBDATA,49,6.05D4 ! BULK MODULUS AT TIME = INFINITY
TBDATA,50,3 ! THREE MAXWELL ELEMENTS FOR SHEAR RELAXATION
TBDATA,51,0.422 ! COEFF. FOR SHEAR RELAXATION LOCATIONS 51-53
TBDATA,52,0.423
TBDATA,53,0.155
TBDATA,61,0.0689 ! RELAXATION TIMES FOR SHEAR RELAXATION
TBDATA,62,0.0065 ! LOCATIONS 61-63
TBDATA,63,0.0001
TBDATA,71,0 ! NO BULK MODULUS RELAXATION
*END
*USE,MAC1 ! EXECUTE MACRO FOR MATERIAL PROPERTIES
:COM, CREATE FINITE ELEMENT MODEL
N,1,
N,3,,0.00025
FILL
N,5,0,(0.00025+0.00325)
FILL
NGEN,3,10,1,5,1,.001
MAT,2
E,1,21,23,3,11,22,13,2
MAT,1
E,3,23,25,5,13,24,15,4
/COM, APPLY BOUNDARY CONDITIONS AND COUPLING
NSEL,S,LOC,Y
DSYM,SYMM,Y
NSEL,S,LOC,X
DSYM,SYMM,X
NSEL,ALL
D,1,ALL
CP,1,UX,21,22,23,24,25
CP,2,UY,2,22
CP,3,UY,3,13,23
CPSGEN,2,2,2,3,1
FINISH
/COM SINCE THE SOLUTION OUTPUT IS VOLUMINOUS IT IS DIVERTED TO A
/COM SCRATCH FILE
/OUTPUT,SCRATCH
*CREATE,MAC2 ! CREATE MACRO FOR ANALYSIS TYPE AND LOADING
/SOLU
SOLCONTROL,0
ANTYPE,STATIC
/COM, TEMPERATURE SET UP
TREF,618
TOFFST,273
TUNIF,618
TIME,1E-5
CNVTOL,F,,,,.00001 ! VERY SMALL MINIMUM ENFORCED
! FOR CONVERGENCE
SOLVE
OUTRES,ESOL,1 ! STORE RESULTS FOR EVERY SUBSTEP
NSUBST,200
TUNIF,460 ! COOLING
TIME,3160
SOLVE
TIME,(14400+3160) ! ISOTHERMAL HOLD
SOLVE
TUNIF,18 ! FURTHER COOLING
TIME,(14400+12000)
SOLVE
*END
FINISH
*USE,MAC2 ! EXECUTE ANALYSIS AND LOADING MACRO
/OUTPUT
/POST26
ESOL,2,2,,BFE,TEMP
ESOL,3,2,3,S,X,STRESS
*CREATE,MAC3 ! MACRO FOR PROCESSING RESULTS
XVAR,2
/GRID,1
/AXLAB,X,TEMPERATURE
/AXLAB,Y,IN-PLANE STRESS (MPA)
PLVAR,3
*GET,MXSX,VARI,3,EXTREM,VMAX ! MAXIMUM IN-PLANE STRESS
NSTORE,20 ! STORE EVERY 20TH TIME POINT RESULTS
PRVAR,2,3
*END
*USE,MAC3 ! EXECUTE POSTPROCESSING MACRO
*SET,P1,(MXSX)
*GET,T1,VARI,3,EXTREM,TMAX
*GET,TE,VARI,2,RTIME,T1
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'PRES MX ','TEMP '
LABEL(1,2) = 'MPa','DEG C'
*VFILL,VALUE(1,1),DATA,12.5,460
*VFILL,VALUE(1,2),DATA,P1,TE
*VFILL,VALUE(1,3),DATA,ABS(P1/12.5),ABS(TE/460)
SAVE,TABLE_1
FINISH
/CLEAR,NOSTART ! CLEAR THE DATABASE
JPGPRF,500,100,1 ! MACRO TO SET PREFS FOR JPEG PLOTS
/PREP7
/TITLE, VM200, VISCOELASTIC SANDWICH SEAL ANALYSIS
/COM, ----- 3-D ANALYSIS -----
ET,1,89 ! 3-D VISCOELASTIC ELEMENT
*USE,MAC1 ! EXECUTE MACRO FOR MATERIAL PROPERTIES
/COM, CREATE FINITE ELEMENT MODEL
N,1,
N,3,0.00025
FILL
N,5,(0.00025+0.00325)
FILL
NGEN,3,10,1,5,1,,.001
NGEN,3,100,1,25,1,,,0.001
MAT,2
E,1,3,23,21,201,203,223,221
EMORE,2,13,22,11,202,213,222,211
EMORE,101,103,123,121
EGEN,2,2,1,1,1,-1
NSLE,S
NSEL,INVE
NDELE,ALL
NSLE,S
/COM, APPLY BOUNDARY CONDITIONS AND COUPLING
NSEL,S,LOC,Y
DSYM,SYMM,Y
NSEL,S,LOC,X
DSYM,SYMM,X
NSEL,S,LOC,Z
DSYM,SYMM,Z
NSEL,S,LOC,Y,0.002
CP,1,UY,ALL
NSEL,S,LOC,Z,0.002
CP,2,UZ,ALL
NSEL,S,LOC,X,0.00025
CP,3,UX,ALL
NSEL,S,LOC,X,0.0035
CP,4,UX,ALL
NSEL,ALL
FINISH
/COM, SINCE THE SOLUTION OUTPUT IS VOLUMINOUS IT IS DIVERTED TO A
/COM, SCRATCH FILE
/OUTPUT,SCRATCH
*USE,MAC2 ! EXECUTE ANALYSIS AND LOADING MACRO
/OUTPUT
/POST26
ESOL,2,2,,BFE,TEMP
ESOL,3,2,3,S,Y,STRESS
*USE,MAC3 ! EXECUTE POSTPROCESSING MACRO
*SET,P2,(MXSX)
*GET,T2,VARI,3,EXTREM,TMAX
*GET,TE2,VARI,2,RTIME,T2
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'PRES MX ','TEMP '
LABEL(1,2) = 'MPa','DEG C'
*VFILL,VALUE(1,1),DATA,12.5,460
*VFILL,VALUE(1,2),DATA,P2,TE2
*VFILL,VALUE(1,3),DATA,ABS(P2/12.5),ABS(TE2/460)
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm200,vrt
/COM,------------------- VM200 RESULTS COMPARISON --------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
/COM,RESULTS USING VISCO88
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,RESULTS USING VISCO89
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.1,' ',F10.1,' ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
/NOPR
/DELETE,TABLE_1
/DELETE,TABLE_2
/DELETE,MAC1
/DELETE,MAC2
/DELETE,MAC3
FINISH
*LIST,vm200,vrt

xuruikl 发表于 2006-12-18 10:21

然后再贴几个其他的例子
FINI
/CLE
/PREP7

!建立有限元模型
ET,1,VISCO107
N,1
N,2,1E-2
N,3,1E-2,1E-2
N,4,,1E-2
NGEN,2,4,1,4,1,,,1E-2
E,1,2,3,4,5,6,7,8
D,1,ALL,,,2
D,5,ALL,,,6
Save,visoplas,db

!定义粘弹性材料参数
Resume,visoplas,db
MP,EX,1,60.6E9
MP,NUXY,1,0.4999
TB,ANAND,1   !!!!关键,定义材料内型
TBDATA,1,29.7E6
TBDATA,2,21.08999E3
TBDATA,3,1.91E7
TBDATA,4,7.0
TBDATA,5,0.23348
TBDATA,6,1115.6E6
TBDATA,7,18.92E6
TBDATA,8,0.07049
TBDATA,9,1.3
FINISH

!求解(静力分析)
/SOLU
ANTYPE,STATIC
NLGEOM,ON ! 打开几何大变形
OUTRES,RSOL,ALL
BFUNIF,TEMP,673 !施加初始温度
D,3,ALL,0.0,,8
TIME,0.000001
SOLVE
NSUBST,20 !定义该载荷步的子步数
D,3,UX,0.2E-2,,4
D,7,UX,0.2E-2,,8
TIME,20
SOLVE
FINISH

!后处理
/POST26
RFORCE,2,3,F,X
RFORCE,3,4,F,X
RFORCE,4,7,F,X
RFORCE,5,8,F,X
ADD,6,2,3,4
ADD,7,6,5,,LOAD
PRVAR,7
*GET,F1,VARI,7,RTIME,20
FINISH

xuruikl 发表于 2006-12-18 10:23

fini
/cle
/fil,exam0610
/COM, Structural
/config,NRES,6000
/prep7
et,1,beam23
r,1,10*9,10*9**3/12,9,,,,
mp,ex,1,3.5e10
mp,prxy,1,0.3
mp,dens,1,7800
acel,9.8,
k,1
k,2,10
l,1,2
lsel,all
latt,1,1,1
esize,5
lmesh,all
nsel,s,loc,x,0,40
esln,s,1,all
cm,kuai0,elem
allsel,all
finish
/solu
eqslv,sparse
time,7
NLGEON,ON
NROPT,FULL
ESTIF,1e-5
ALLSEL
EKILL,ALL
allsel
nsel,s,loc,x,0
d,all,all
allsel
bfunif,temp,300
ncnv,2
kbc,1
autots,on
tb,creep,1
tbdata,1,0,0,1
nsubst,40
outpr,basic,1
outres,epcr,1
solve
save
rate,1
esel,s,,,kuai0
ealive,all
esel,s,live
nsle,s
NSEL,INVE
D,ALL,ALL,0
allsel
nsel,s,loc,x,0
d,all,all
time,100
tb,creep,1
tbdata,1,1e-5,0,1,0,0,
allsel
solve
finish
save

xuruikl 发表于 2006-12-18 10:25

还有一些还没来的及整理
有兴趣的话我再整理整理发上来

venture 发表于 2006-12-18 21:25

估计很多人没有做过这方面的，如果楼主能结合理论与自己的实例总结一下就好了。

sunleiupc 发表于 2007-5-12 08:44

请教：蠕变系数怎么选择

蠕变系数怎么选择哪
跟材料性能和温度有关？在什么地方可以查到阿？

weiky2008 发表于 2008-6-5 20:46

是ansys下的分析案例？:handshake

16443 发表于 2008-6-5 21:05

回复 11楼 的帖子

是的，看帖子仔细点么。
/COM,ANSYS MEDIA REL. 10.0 (05/31/2005) REF. VERIF. MANUAL: REL. 10.0

yagn 发表于 2008-6-14 10:05

赞楼主，学习了，谢谢楼主分享啊

mututu_gui 发表于 2008-6-18 17:32

RE:可否多贴些不是ANSYS verification里的蠕变例子

可否多贴些不是ANSYS verification里的蠕变例子？

scubme 发表于 2009-4-4 11:11

请问楼主
TUNIF,HOT    这句该怎么理解？hot没定义，采用ansys默认值，认为是一个无限接近0的值？
谢谢！
页: [1] 2 3
查看完整版本: 贴一些蠕变分析例子