桥梁的地震响应分析【转】
/filname,earthquake,1
keyw,pr_struc,1
/prep7
!定义单元类型
et,1,beam3
!定义实常数
r,1,0.0256,0.546e-4,0.16
!定义材料属性
mp,ex,1,2.1e11
mp,prxy,1,0.3
mp,dens,1,7800
!建立几何模型
k,1
k,2,100
k,3,50,25
l,1,2
larc,1,2,3
ldiv,1,,,10
ksel,s,kp,,4,12,1
kgen,2,all,,,,30
kdele,3
*do,i,4,12,1
l,i,i+9
*enddo
lsel,s,line,,12,20,1
lsel,a,line,,2
lsbl,2,all
l,4,22
*do,i,5,11,1
l,i,i+19
*enddo
l,12,23
allsel
numcmp,all
!网格划分、施加边界条件
lesize,all,,,1
type,1
real,1
mat,1
lmesh,all
!边界条件
nsel,s,loc,x,0
nsel,a,loc,x,100
d,all,uy
nsel,s,loc,x,0
d,all,ux
allsel
!自重载荷
acel,,9.81
allsel
!地震谱响应分析
/solu
!模态分析
antype,2
MODOPT,SUBSP,28!子空间法，模态提取数为28
solve
finish
!谱分析
/solu
antype,8 !spectrum
SPOPT,SPRS,28,1 !单点谱分析，参与计算的模态数为28，打开盈利响应开关
SVTYP,2,1, !设置反应谱类型为加速度谱，
SED,1,1,0, !激励方向为x和y
FREQ,0.333,0.357,0.416,0.5,0.625,0.833,1.25,2.5,2.778
FREQ,3.333,3.571,4.167,5,6.25,8.333,10,12.5,16.667
FREQ,25,50
SV,0,0.013,0.013884,0.01595,0.018794,0.022974,0.029763,0.042871,0.08,0.08,
SV,0,0.08,0.08,0.08,0.08,0.08,0.08,0.08,0.0712,0.0624,
SV,0,0.0536,0.0448,
solve
finish
!模态扩展
/solu
antype,2
MODOPT,SUBSP,28
mxpand,28,0,0,1,0.005!扩展模态数设为28，计算单元的计算结果设置为yes，临界点设为0.005
solve
finish
!模态合并
/solu
antype,8
SRSS,0.02,DISP!组合方式为srss，significant threshold为0.02
solve
finish
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!地震波瞬态分析
*DIM,tjx,ARRAY,2,50,1
*DIM,tjy,ARRAY,2,50,1
*CREATE,ansuitmp
*VREAD,tjx(1,1),'tjx','txt',' ',50
(e9.3,e11.3)
*END
/INPUT,ansuitmp
*CREATE,ansuitmp
*VREAD,tjy(1,1),'tjy','txt',' ',50
(e9.3,e11.3)
*END
/INPUT,ansuitmp
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!以下是一个矩阵形成的例子
!*dim,aa,,2,3
!*CREATE,ansuitmp
!*vread,aa(1,1),'data','dat',,jik,3,2
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
antype,4
TRNOPT,FULL
LUMPM,0
*do,t,1,50,1 !地震波时间5秒，时间间隔0.1
time,0.1*t !每一个加载步的求解时间
kbc,0 !每个加载步的加载形式为rump
nsub,10 !每一个加载步分为10个子步
acel,tjx(2,t),tjy(2,t) !施加横向、竖向加速度
nsel,all
solve !求解
*enddo
先谢谢了，能否请教一下，怎样在瞬态分析中施加正弦荷载？
页:
[1]